home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD006b.dsk / HISTORY.QUIZ.bas < prev    next >
BASIC Source File  |  2003-06-12  |  3KB  |  98 lines
  1. 5 D$ =  CHR$(4)
  2. 10  HOME : VTAB 3: HTAB (40 -28)/2: INVERSE : PRINT " PEOPLE IN AMERICAN HISTORY ": NORMAL 
  3. 15  PRINT : PRINT "     IN THIS GAME YOU WILL THINK OF A   PERSON IN AMERICAN HISTORY AND THE      COMPUTER WILL TRY TO GUESS HIM OR HER."
  4. 16  PRINT 
  5. 20  PRINT : PRINT "     IF THE COMPUTER FAILS, IT WILL ASK YOU TO PROVIDE A QUESTION WHICH WILL    DISTINGUISH BETWEEN THE PERSON YOU HAD  IN MIND AND THE COMPUTER'S CLOSEST      GUESS."
  6. 25  PRINT : PRINT 
  7. 30  PRINT : HTAB 15: INVERSE : PRINT " GOOD LUCK! ": NORMAL 
  8. 40  GOSUB 1000
  9. 70  DIM A$(200)
  10. 75  GOSUB 1001
  11. 110 N =  VAL(A$(0))
  12. 120  REM 
  13. 130  HOME : INPUT "ARE YOU THINKING OF SOMEONE FROM        AMERICAN HISTORY?  ";A$
  14. 132  IF  LEFT$(A$,1) = "N"  THEN  INPUT "DO YOU WANT TO QUIT? ";X$: IF  LEFT$(X$,1) = "Y"  THEN 1090
  15. 133  IF  LEFT$(X$,1) = "N"  THEN 130
  16. 135  PRINT 
  17. 140  IF A$ = "LIST"  THEN 600
  18. 150  IF  LEFT$(A$,1) < >"Y"  THEN 120
  19. 160 K = 1
  20. 170  GOSUB 390
  21. 180  IF  LEN(A$(K)) = 0  THEN 999
  22. 190  IF  LEFT$(A$(K),2) = "/Q"  THEN 170
  23. 195  PRINT 
  24. 200  PRINT "IS IT "; RIGHT$(A$(K), LEN(A$(K)) -2);
  25. 210  INPUT "  ";A$
  26. 215  PRINT 
  27. 220 A$ =  LEFT$(A$,1)
  28. 230  IF A$ = "Y"  THEN  PRINT "WHY NOT TRY ANOTHER HISTORIC FIGURE?": FOR I = 1 TO 500: NEXT I: GOTO 120
  29. 240  PRINT "WHO WERE YOU THINKING OF?  ": INPUT "   ";V$: PRINT 
  30. 250  PRINT "PLEASE TYPE A QUESTION THAT WOULD       DISTINGUISH  ";
  31. 260  PRINT V$: PRINT " FROM "; RIGHT$(A$(K), LEN(A$(K)) -2);"."
  32. 270  INPUT X$
  33. 275  PRINT 
  34. 280  PRINT "FOR A ";V$;" THE ANSWER WOULD BE";
  35. 290  INPUT "   ";A$
  36. 300 A$ =  LEFT$(A$,1): IF A$ < >"Y"  AND A$ < >"N"  THEN 280
  37. 310  IF A$ = "Y"  THEN B$ = "N"
  38. 320  IF A$ = "N"  THEN B$ = "Y"
  39. 330 Z1 =  VAL(A$(0))
  40. 340 A$(0) =  STR$(Z1 +2)
  41. 350 A$(Z1) = A$(K)
  42. 360 A$(Z1 +1) = "/A" +V$
  43. 370 A$(K) = "/Q" +X$ +"/" +A$ + STR$(Z1 +1) +"/" +B$ + STR$(Z1) +"/"
  44. 380  GOTO 120
  45. 390  REM 
  46. 400 Q$ = A$(K)
  47. 410  FOR Z = 3 TO  LEN(Q$)
  48. 415  IF  MID$ (Q$,Z,1) < >"/"  THEN  PRINT  MID$ (Q$,Z,1);: NEXT Z
  49. 420  INPUT C$
  50. 425  PRINT 
  51. 430 C$ =  LEFT$(C$,1)
  52. 440  IF C$ < >"Y"  AND C$ < >"N"  THEN 410
  53. 450 T$ = "/" +C$
  54. 455  FOR X = 3 TO  LEN(Q$) -1
  55. 460  IF  MID$ (Q$,X,2) = T$  THEN 480
  56. 470  NEXT X
  57. 475  STOP 
  58. 480  FOR Y = X +1 TO  LEN(Q$)
  59. 490  IF  MID$ (Q$,Y,1) = "/"  THEN 510
  60. 500  NEXT Y
  61. 510 K =  VAL( MID$ (Q$,X +2,Y -X -2))
  62. 520  RETURN 
  63. 600  PRINT : PRINT "THE HISTORIC FIGURES I ALREADY KNOW ARE:"
  64. 605 X = 0
  65. 610  FOR I = 1 TO 200
  66. 620  IF  LEFT$(A$(I),2) < >"/A"  THEN 650
  67. 630  FOR Z = 3 TO  LEN(A$(I))
  68. 640  IF  MID$ (A$(I),Z,1) < >"/"  THEN  PRINT  MID$ (A$(I),Z,1);: NEXT Z
  69. 641  PRINT  TAB( 20);
  70. 645 X = X +1: IF X >1  THEN X = 0: PRINT 
  71. 650  NEXT I
  72. 660  GOSUB 1000
  73. 680  GOTO 120
  74. 999  END 
  75. 1000  POKE  -16368,0: VTAB 24: INVERSE : INPUT "PRESS RETURN TO GO ON";AB$: NORMAL : RETURN 
  76. 1001  HOME : INPUT "WHICH CLASS IS THIS?";NA$
  77. 1002  PRINT : INPUT "HAS THIS CLASS PLAYED BEFORE?  ";XY$
  78. 1003  IF  LEFT$(XY$,1) = "N"  THEN XY$ = NA$:NA$ = "":FL = 1: GOTO 1010
  79. 1004  IF  LEFT$(XY$,1) < >"Y"  THEN 1002
  80. 1010  PRINT D$;"OPEN HIST-FILE";NA$
  81. 1020  PRINT D$;"READ HIST-FILE";NA$
  82. 1030  INPUT A$(0)
  83. 1040  FOR I = 1 TO  VAL(A$(0))
  84. 1050  INPUT A$(I)
  85. 1060  NEXT I
  86. 1070  PRINT D$;"CLOSE HIST-FILE";NA$
  87. 1075  IF FL = 1  THEN NA$ = XY$
  88. 1080  RETURN 
  89. 1090  PRINT D$;"OPEN HIST-FILE";NA$
  90. 2000  PRINT D$;"DELETEHIST-FILE";NA$
  91. 2005  PRINT D$;"OPEN HIST-FILE";NA$
  92. 2010  PRINT D$;"WRITE HIST-FILE";NA$
  93. 2020  PRINT A$(0)
  94. 2030  FOR I = 1 TO  VAL(A$(0))
  95. 2040  PRINT A$(I)
  96. 2050  NEXT I
  97. 2060  PRINT D$;"CLOSE HIST-FILE";NA$
  98. 2070  END